[devel] Re: alternatives

[Mikhail Zabaluev <mhz@altlinux.org>]

[-- Attachment #1.1: Type: text/plain, Size: 1739 bytes --]

Hello Stanislav,

On Tue, Apr 01, 2003 at 11:37:04AM +0400, Stanislav Ievlev wrote:
>
> Привет!
> 
> On Tue, Apr 01, 2003 at 03:09:43AM +0400, Mikhail Zabaluev wrote:
> > > программ. При переходе на собственный конфигуратор это позволит облегчить
> > > написание backend к нему.
> > 
> > Не стоит ради упрощения одного инструмента создавать проблемы всем
> > разработчикам, которым эти файлы предстоит писать.
> > Если так уж необходимо приведение к общему формату, можно гонять
> > туда-обратно при помощи XSLT.
> Я уже думал и про это. Во-первых формат не слишком сложен чтобы
> разработчикам его использовать (это конечно же субъективно, сделай
> короткий вариант, найдется кто-нибудь кому и это будет неудобно, xml сам
> по себе достаточно громоздок), да и не надо его использовать каждый день. 
> Во-вторых, я конечно же думал сделать специализированные 
> форматы с перегонкой на общий через XSLT, но не могу
> никак себя убедить что проще иметь десяток разных обработчиков +
> транслятор, чем изначально один обработчик . Я
> предпочитаю наблюдать все баги в одном месте, а не десяти.

Я бы обратил логику: транслятор/обработчик пишется и отлаживается
один раз, а файлы создаются и редактируются постоянно. Где
будут чаще всего возникать ошибки?

К тому же, если всё-таки соберётесь делать schema,
замучаетесь с определением валидности каждого из приложений
общего формата. Со специализированным форматом это сделать
гораздо проще.

Короче, приложены два XSL-преобразования для перегонки
между обсуждаемыми форматами в обе стороны.
Надеюсь, это поможет продвинуться на Истинном Пути XML :)

-- 
Stay tuned,
  MhZ                                     JID: mhz@altlinux.org
___________
filesystem not big enough for Jumbo Kernel Patch

[-- Attachment #1.2: alternatives-bloat.xsl --]
[-- Type: text/xml, Size: 1254 bytes --]

<?xml version="1.0"?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	       version="1.0">

<!-- Transform alternatives file from the proposed brief format to 
     the "common" bloated configuration format -->

<xsl:output method="xml" indent="yes"/>

<xsl:template match="/link">
  <group name="candidate">
    <option name="link" type="string">
      <xsl:attribute name="value">
        <xsl:value-of select="@name"/>
      </xsl:attribute>
    </option>
    <option name="real" type="string">
      <xsl:attribute name="value">
        <xsl:value-of select="@target"/>
      </xsl:attribute>
    </option>
    <option name="weight" type="number">
      <xsl:attribute name="value">
        <xsl:value-of select="@priority"/>
      </xsl:attribute>
    </option>
    <xsl:apply-templates select="slave"/>
  </group>
</xsl:template>

<xsl:template match="slave">
  <group name="slave">
    <option name="link" type="string">
      <xsl:attribute name="value">
        <xsl:value-of select="@name"/>
      </xsl:attribute>
    </option>
    <option name="real" type="string">
      <xsl:attribute name="value">
        <xsl:value-of select="@target"/>
      </xsl:attribute>
    </option>
  </group>
</xsl:template>

</xsl:transform>

[-- Attachment #1.3: alternatives-debloat.xsl --]
[-- Type: text/xml, Size: 1080 bytes --]

<?xml version="1.0"?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	       version="1.0">

<!-- Transform alternatives file from the "common"
     bloated configuration format to the proposed brief format -->

<xsl:output method="xml" indent="yes"/>

<xsl:template match="/group[@name='candidate']">
  <link>
    <xsl:attribute name="name">
      <xsl:value-of select="option/@value[../@name='link']"/>
    </xsl:attribute>
    <xsl:attribute name="target">
      <xsl:value-of select="option/@value[../@name='real']"/>
    </xsl:attribute>
    <xsl:attribute name="priority">
      <xsl:value-of select="option/@value[../@name='weight']"/>
    </xsl:attribute>
    <xsl:apply-templates select="group"/>
  </link>
</xsl:template>

<xsl:template match="group[@name='slave']">
  <slave>
    <xsl:attribute name="name">
      <xsl:value-of select="option/@value[../@name='link']"/>
    </xsl:attribute>
    <xsl:attribute name="target">
      <xsl:value-of select="option/@value[../@name='real']"/>
    </xsl:attribute>
  </slave>
</xsl:template>

</xsl:transform>

[-- Attachment #2: Type: application/pgp-signature, Size: 189 bytes --]