[Comm] procmail и рассылки

["Alexey I. Froloff" <raorn@immo.ru>]

[-- Attachment #1: Type: text/plain, Size: 1433 bytes --]

Помнится, как-то на irc Александр Боковой в ответ на мою фразу о
том, что меня ломает подписываться на ещё один maillist, потому
как ломает добавлять правило в .procmailrc, ответил, что у него
на все рассылки одно правило. Мне эта идея понравилась и я решил
его правило слегка пропатчить...

Смысл в следующем - все списки рассылки идут в mbox'ы в каталоге
$MAILDIR/lists в виде <prefix>-<list-name>, где prefix либо
определяется мной, либо берётся домен второго уровня.

.procmailrc:
===
...

:0:
* ^List-Id:.*<\/[^>]*>$
lists/`echo $MATCH | sed -f $MAILDIR/lists.sed`

...
===

$MAILDIR/lists.sed:
===
# Lowercate input...
y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/
# ALT Linux lists
s/^\([^\.]*\)\(\.www\)\?\.\(altlinux\.\(ru\|com\|org\|net\)\|linux\.iplabs\.ru\)>$/alt-\1/;
t end
# LRN lists
s/^\([^\.]*\)\(\.www\)\?\.\(lrn\.\(ru\|com\|org\|net\)\|linux\.ru\.net\)>$/lrn-\1/;
t end
# GNU/NonGNU
s/^\([^\.]*\)\.\(non\)\?gnu\.org>$/gnu-\1/;
t end
# SourceForge
s/^\([^\.]*\)\.lists\.sourceforge\.net>$/sf-\1/;
t end
# QuakeForge
s/^\([^\.]*\)\.lists\.quakeforge\.net>$/qf-\1/;
t end
# Insert more patterns here...
#s/^\([^\.]*\)\.blah\.bl.ah>$/blah-\1/;
#t end
# Default rule - prefix list with 2-level domain name
s/^\([^\.]*\)\.\([^\.]*\.\)*\([^\.]*\)\.[^\.]*>$/\3-\1/;
:end
===

-- 
Regards, Sir Raorn.
-------------------
Не думаю, что этот случай стоит специального официального заявления.
		-- ldv in sisyphus@

[-- Attachment #2: Type: application/pgp-signature, Size: 189 bytes --]