#compdef gear

local curcontext="$curcontext" ret=1

_arguments -S \
    '(-v --verbose -q --quiet)'{-q,--quiet}'[try to be more quiet]' \
    '(-v --verbose -q --quiet)'{-v,--verbose}'[print a message for each action]' \
    '(- :)'{-V,--version}'[print program version and exit]' \
    '(- :)'{-h,--help}'[show usage and exit]' \
    '(-r --rules)'{-r,--rules=}'[name of file with rules]:rules file:_files' \
    '(-t --tree-ish)'{-t,--tree-ish=}'[tree, commit or tag object name]:tree-ish' \
    - 'export' \
    '(--export-dir --no-compress --bzip2 --gzip)--no-compress[do not compress output archive]' \
    '(--export-dir --no-compress --bzip2 --gzip)--bzip2[compress output archive using bzip2]' \
    '(--export-dir --no-compress --bzip2 --gzip)--gzip[compress output archive using gzip]' \
    '(--no-compress --bzip2 --gzip :)--export-dir=[write source files to specified directory]:directory:_directories' \
    ':output tarball:_files' \
    - 'hasher' \
    '--hasher[execute hsh-like command afterwards]' \
    '(-):command: _command_names -e' \
    '*::args: _normal' \
    - 'rpmbuld' \
    '--rpmbuild[execute rpmbuild-like command afterwards]' \
    '(-):command: _command_names -e' \
    '*::args: _normal' \
    && ret=0